Quote:

---

However I need the folders in the original format at the end. If the WinRAR files were in the format you suggested then I would just select them all the decompress...

---

---

C:\Program Files\WinRAR>rar /?
RAR 3.70 beta 1   Copyright (c) 1993-2007 Alexander Roshal   8 Jan 2007
Registered to Mike
(etc)

---

---

@echo off
REM place this batch file in the top folder
REM and run it from there
if exist "%temp%\rardirlist.txt" del "%temp%\rardirlist.txt" > nul
if exist "%temp%\subdirlist.txt" del "%temp%\subdirlist.txt" > nul

REM remember where we are
set topfolder=%CD%

REM get a list of all the subfolders
REM under this one and put it in
REM a temp file
dir /b /s /ad > "%temp%\subdirlist.txt"

REM in a loop check each one for presence of
REM rar files, write folder name to another list
REM if any found
for /F "delims==" %%a in (%temp%\subdirlist.txt) do (
	cd %%a
	if exist *.rar echo %%a >> "%temp%\rardirlist.txt"
	)

REM for each folder that contains RARs
REM cd to that folder and extract
for /F "delims==" %%a in (%temp%\rardirlist.txt) do (
	cd %%a
	"c:\program files\winrar\rar.exe" e *.rar
	)

REM clean up
del "%temp%\subdirlist.txt" > nul
del "%temp%\rardirlist.txt" > nul

REM go back to where we were
cd %topfolder%

---

---

@echo off

REM place this batch file in the top folder

REM and run it from there



if exist "rardirlist.txt" del "rardirlist.txt" > nul

if exist "subdirlist.txt" del "subdirlist.txt" > nul



REM remember where we are

set topfolder=%CD%



REM get a list of all the subfolders

REM under this one and put it in a temp file

dir /b /s /ad > "subdirlist.txt"



REM in a loop check each one for  rar files

REM write folder name to another list if any found

for /F "delims==" %%a in (subdirlist.txt) do (

	cd %%a

	if exist *.rar echo %%a >> "rardirlist.txt"

	)



REM for each folder that contains RARs

RE enter folder and extract

for /F "delims==" %%a in (rardirlist.txt) do (

	cd %%a

	"c:\program files\winrar\rar.exe" e *.rar

	)



REM clean up 

del "subdirlist.txt" > nul

del "rardirlist.txt" > nul



REM go back to where we were

cd %topfolder%

---

---

@echo off
REM place this batch file in the top folder
REM and run it from there

REM remember where we are
set topfolder=%CD%

if exist "%topfolder%\subdirlist.txt" del "%topfolder%\subdirlist.txt" > nul
if exist "%topfolder%\rardirlist.txt" del "%topfolder%\rardirlist.txt" > nul
echo.
echo (1) creating list of all sub folders...
echo.

REM get a list of all the subfolders
REM under this one and put it in a temp file
dir /b /s /ad > "%topfolder%\subdirlist.txt"

echo all sub folders...
echo.
type "%topfolder%\subdirlist.txt"
echo.
pause
echo.
echo (2) finding folders with rars in them
echo.

REM in a loop check each one for  rar files
REM write folder name to another list if any found
for /F "delims==" %%a in ('type "%topfolder%\subdirlist.txt"') do (
	cd %%a
	if exist *.rar echo %%a >> "%topfolder%\rardirlist.txt"
	)

echo all sub folders with Rars in...
echo.
type "%topfolder%\rardirlist.txt"
echo.
pause
echo.
echo (3) extracting from Rar archives
echo.
echo ready to start...
echo.
pause
echo.
REM for each folder that contains RARs
REM enter folder and extract
for /F "delims==" %%a in ('type "%topfolder%\rardirlist.txt"') do (
	echo.
	echo expanding rars in %%a
	echo.

	cd %%a
	"c:\program files\winrar\rar.exe" e *.rar
	)

REM clean up
rem del "%topfolder%\subdirlist.txt" > nul
rem del "%topfolder%\rardirlist.txt" > nul

REM go back to where we were
cd %topfolder%
echo.
echo (4) Finished
echo.
pause
echo.

---

Originally posted by aweathe:

---

1. "for /F" means for all folders in the current directory?

---

Quote:

---

Finally, the part of the code that has the problem is copied here:
""
REM in a loop check each one for rar files
REM write folder name to another list if any found
for /F "delims==" %%a in ('type "%topfolder%\subdirlist.txt"') do (
cd %%a

if exist *.rar echo %%a > "%topfolder%\rardirlist.txt"
)
""
The problem is that the folder "rardirlist.txt" doesn't get created...?

---

---

@echo off
REM place this batch file in the top folder and run it from there
set topfolder=%CD%
for /F "delims==" %%a in ('dir /b /s *.rar') do (
 	cd "%%~Da%%~pa"
	"c:\program files\winrar\rar.exe" e "%%~Da%%~pa%%~nxa" | findstr "Extracting from"
	)
cd %topfolder%

---

Quote:

---

Does subdirlist.txt get created?

---